Сообщений в теме: 7

[SanzySky]

Здравствуйте!

Уважаемые,ответьте пожалуйста-где именно в редакторе третей армы модуль гражданских?или может есть какие то условия для его появления в редакторе?

 

p.s.   может кому и простой вопрос-я перерыл весь редактор_не нашел

 

[SteelRat]

Он ещё не готов, но я себе доделал), так посмотреть на что похоже.

http://arma3.ru/foru...atform/?p=27889

[SanzySky]

Он ещё не готов, но я себе доделал), так посмотреть на что похоже.

http://arma3.ru/foru...atform/?p=27889

спасибо за ответ     посмотрю     

я и раньше скрипты видел про гражданских-просто подумал что модуль есть в самом редакторе

 

еще раз-благодарю!!  

 

p.s.   тему,думаю,пока не закрывать-может кто напишет еще что то про замену модуля гражданских.....

[SteelRat]

Посмотрите на сайте армахолика, пару вариантов точно видел, по моему в этом разделе

Пожалуйста Войдите или Зарегистрируйтесь чтобы увидеть скрытое содержание

Сообщение отредактировал SteelRat: 25 September 2014 - 01:57

[SanzySky]

Посмотрите на сайте армахолика, пару вариантов точно видел, по моему в этом разделе

Пожалуйста Войдите или Зарегистрируйтесь чтобы увидеть скрытое содержание

 

 

 

обизательно посмотрю-если будут вопросы-задам сюда)        спс!

[Dobryi_33RUS]

Вот простейший скрипт заставляющий бота бродить по городу.

 

 

_unit = _this select 0;                                                      // Имя юнита

 

_list = position _unit nearObjects 300;                            // 300 - радиус поиска зданий, относительно бота.

_count_l = count _list;

_bPos = _list select floor random _count_l;

_nBuilding = nearestBuilding _bPos;

_pos = getPos _nBuilding;

 

_wp = group _unit addWaypoint [_pos, 0];

_wp setWaypointType "MOVE";

_wp setWaypointSpeed "LIMITED";

_wp setWaypointBehaviour "CARELESS";

_wp setWaypointTimeout [5, 15, 30];

_wp setWaypointStatements ["true", "null = [this] ExecVM 'Scripts\civil.sqf';"];  

 

 

Подключать так "null =  [Имя бота] ExecVM 'Scripts\civil.sqf';"]" (можно прописывать это в инит боту)  

Сообщение отредактировал Dobryi_33RUS: 19 October 2014 - 07:10

[SteelRat]

/*
	file: fn_agentLoiter.sqf
	
	Логика управляющая перемещением пешего агента
	_agent = createAgent ["C_Man_1", [0,0,0], [], 0, "NONE"];
	
	Пример вызова:
	[_agent, getPos _agent, 200, 100] execVM "fn_agentLoiter.sqf";	//	из кода
	0 = [this, getPos this, 200, 100] execVM "fn_agentLoiter.sqf"	//	из инита бота
	
	Параметры:
	_this select 0 - Объект Бот
	_this select 1 - Координаты позиции относительно которой будет производиться поиск позиции для перемещения Бота
	_this select 2 - Радиус в пределах которого будет производится поиск позиции
	_this select 3 - Дебаг таймер, боты не редко тупят
	
	Для вывода на экран Debug информации добавить в init.sqf миссии строку, или выполнить эту строку в Debug консоли:
	AL_Debug = true;	
	
	created by SteelRat
*/

_agent		= _this select 0;
_center		= _this select 1;
_radius		= _this select 2;
_timeTimer	= _this select 3;

_agent disableAI "FSM";
_agent setBehaviour "SAFE";

_movePos 	= getPos _agent;
_checkTime 	= time;

_debug = !isNil "AL_Debug";

while {alive _agent && !isNull _agent} do {
	
	if ((_agent distance _movePos < 5) or (time > _checkTime)) then {
		
		sleep random 5;
		
		_centerPos = if (typename _center == typename []) then [{_center},{call compile _center}];
		_xPos = (_radius - _radius * 2) + (random (_radius * 2));
		_yPos = (_radius - _radius * 2) + (random (_radius * 2));
		
		_vpPos = [
			(_centerPos select 0) + _xPos,
			(_centerPos select 1) + _yPos, 
			(_centerPos select 2)
		];
		
		_movePos		= [];
		_rad			= 20;
		_expression		= "(1 - sea)";
	
		{
			_test = _x select 0;
			if (!(surfaceIsWater [_test select 0,_test select 1]) && !(isOnRoad _test)) exitWith {_movePos = AslToAtl [_test select 0, _test select 1, (getTerrainHeightASL _test)]};
		} foreach (selectBestPlaces [_vpPos, _rad, _expression, 1, 10]);
	
		if (count _movePos == 0) exitWith {_movePos = getPos _agent};
		
		_checkTime = time + _timeTimer;
		_agent forceSpeed (1 + (round random 2));
		_agent MoveTo _movePos;
		
		if (_debug) then {
			systemChat format["AL: %1: Move: %2", _agent, _movePos];
		};
	};
	
	sleep 0.5;
};

[SteelRat]

ЗЫ

Что бы создать агента через редактор миссий:

 

Ставите на карту, на нужной позиции, объект Logic.

В инит логики пишите

0 = this spawn {
    _lg = _this;
    _agent = createAgent ["C_Man_1", [0,0,0], [], 0, "NONE"];
    sleep 0.005;
    _agent switchMove "";
    _agent setDir (getDir _lg);
    _agent setPos (getPos _lg);
    sleep 0.005;
    [_agent, getPos _agent, 200, 100] execVM "fn_agentLoiter.sqf";

    deleteVehicle _lg;
}

Сообщение отредактировал SteelRat: 20 October 2014 - 17:37