12 replies to this topic

[romylq]

Как создать заложников? Чтоб они сидели или лежали связанные, и по кнопке через меню их освобождать.

[Galet]

в ините пленника-ов [this] execVM "hostage.sqf"

hostage.sqf

// Set AI Hostage Script 

// By Galactic Twinkles

// Define Captive

_captive = _this select 0;

// Select random animation

_anim = selectRandom ["Acts_AidlPsitMstpSsurWnonDnon01","Acts_AidlPsitMstpSsurWnonDnon02","Acts_AidlPsitMstpSsurWnonDnon03","Acts_AidlPsitMstpSsurWnonDnon04","Acts_AidlPsitMstpSsurWnonDnon05","Acts_ExecutionVictim_Loop"];

 

// Set Captive Settings

_captive setCaptive true;

// Remove Items

removeAllWeapons _captive;

removeBackpack _captive;

removeVest _captive;

removeAllAssignedItems _captive;

_captive switchMove _anim; // SwitchMove to random animation

// Set unit as hurt if it's the Execution animation

if (_anim == "Acts_ExecutionVictim_Loop") then {

_captive setDamage .5;

};

_captive disableAI "MOVE"; // Disable AI Movement

_captive disableAI "AUTOTARGET"; // Disable AI Autotarget

_captive disableAI "ANIM"; // Disable AI Behavioural Scripts

_captive allowFleeing 0; // Disable AI Fleeing

_captive setBehaviour "Careless"; // Set Behaviour to Careless because, you know, ARMA AI.

 

// Add Hold Action to Free Hostage

[

/* 0 object */         _captive,

/* 1 action title */ "Освободить заложников",

/* 2 idle icon */ "\a3\ui_f\data\IGUI\Cfg\HoldActions\holdAction_unbind_ca.paa",

/* 3 progress icon */ "\a3\ui_f\data\IGUI\Cfg\HoldActions\holdAction_unbind_ca.paa",

/* 4 condition to show */ "true",

/* 5 condition for action */ "true",

/* 6 code executed on start */ {},

/* 7 code executed per tick */ {},

/* 8 code executed on completion */       {

        if (_this select 3 select 0 == "Acts_ExecutionVictim_Loop") then {

_this select 0 playMove "Acts_ExecutionVictim_Unbow";

} else {

_this select 0 switchMove "Acts_AidlPsitMstpSsurWnonDnon_out";

};

_complMessage = selectRandom ["Я думал, что я умру здесь!","Большое вам спасибо.","Я кажеться напрудил в свои штаны ...","Можно мне тебя обнять?","Я ЖИВ.","Где я, черт возьми?"];

["Заложник", _complMessage] remoteExec ["BIS_fnc_showSubtitle"];

sleep 5.5;

(_this select 0) enableAI "MOVE";

(_this select 0) enableAI "AUTOTARGET";

(_this select 0) enableAI "ANIM";

(_this select 0) setBehaviour "SAFE";

[(_this select 0)] joinSilent player;

[(_this select 0),(_this select 2)] remoteExec ["bis_fnc_holdActionRemove",[0,-2] select isDedicated,true];

 

},

/* 9 code executed on interruption */       {

_intrMessage = selectRandom ["Эй! Я не хочу здесь умереть!","Мужик! Не оставляй меня здесь! Пожалуйста!","ЕСТЬ! ЕСТЬ! ЛЮДИ. ВЫТАЩИ МЕНЯ ОТСЮДА.","Дерьмо дерьмо дерьмо ..."];

["Заложник", _intrMessage] remoteExec ["BIS_fnc_showSubtitle"];

    },

/* 10 arguments */     [_anim],

/* 11 action duration */     3,

/* 12 priority */     0,

/* 13 remove on completion */     true,

/* 14 show unconscious */     false

] remoteExec ["BIS_fnc_holdActionAdd",[0,-2] select isDedicated,true];

[32bit]

Спасибо большой за скрипт, подскажите только как это привязать к тригеру чтобы когда я к примеру освободил 3 заложников миссия завершилась.

[Schatten]

32bit, во-первых, нужно немного изменить код:

// Set AI Hostage Script
// By Galactic Twinkles
// Define Captive
_captive = _this select 0;
// Select random animation
_anim = selectRandom ["Acts_AidlPsitMstpSsurWnonDnon01","Acts_AidlPsitMstpSsurWnonDnon02","Acts_AidlPsitMstpSsurWnonDnon03","Acts_AidlPsitMstpSsurWnonDnon04","Acts_AidlPsitMstpSsurWnonDnon05","Acts_ExecutionVictim_Loop"];

// Set Captive Settings
_captive setCaptive true;
// Remove Items
removeAllWeapons _captive;
removeBackpack _captive;
removeVest _captive;
removeAllAssignedItems _captive;
_captive switchMove _anim; // SwitchMove to random animation
// Set unit as hurt if it's the Execution animation
if (_anim == "Acts_ExecutionVictim_Loop") then {
	_captive setDamage .5;
};
_captive disableAI "MOVE"; // Disable AI Movement
_captive disableAI "AUTOTARGET"; // Disable AI Autotarget
_captive disableAI "ANIM"; // Disable AI Behavioural Scripts
_captive allowFleeing 0; // Disable AI Fleeing
_captive setBehaviour "Careless"; // Set Behaviour to Careless because, you know, ARMA AI.

// Add Hold Action to Free Hostage
[
	/* 0 object */         _captive,
	/* 1 action title */ "Освободить заложников",
	/* 2 idle icon */ "\a3\ui_f\data\IGUI\Cfg\HoldActions\holdAction_unbind_ca.paa",
	/* 3 progress icon */ "\a3\ui_f\data\IGUI\Cfg\HoldActions\holdAction_unbind_ca.paa",
	/* 4 condition to show */ "true",
	/* 5 condition for action */ "true",
	/* 6 code executed on start */ {},
	/* 7 code executed per tick */ {},
	/* 8 code executed on completion */       {
		if (isNil "captives") then {
			captives = [_this select 0];
		} else {
			captives pushBack (_this select 0);
		};
		if (((_this select 3) select 0) == "Acts_ExecutionVictim_Loop") then {
			(_this select 0) playMove "Acts_ExecutionVictim_Unbow";
		} else {
			(_this select 0) switchMove "Acts_AidlPsitMstpSsurWnonDnon_out";
		};
		_complMessage = selectRandom ["Я думал, что я умру здесь!", "Большое вам спасибо.", "Я кажеться напрудил в свои штаны ...", "Можно мне тебя обнять?", "Я ЖИВ.", "Где я, черт возьми?"];
		["Заложник", _complMessage] remoteExec ["BIS_fnc_showSubtitle"];
		sleep 5.5;
		(_this select 0) enableAI "MOVE";
		(_this select 0) enableAI "AUTOTARGET";
		(_this select 0) enableAI "ANIM";
		(_this select 0) setBehaviour "SAFE";
		[_this select 0] joinSilent player;
		[_this select 0, _this select 2] remoteExec ["bis_fnc_holdActionRemove", [0, -2] select isDedicated, true];
	},
	/* 9 code executed on interruption */       {
		_intrMessage = selectRandom ["Эй! Я не хочу здесь умереть!", "Мужик! Не оставляй меня здесь! Пожалуйста!", "ЕСТЬ! ЕСТЬ! ЛЮДИ. ВЫТАЩИ МЕНЯ ОТСЮДА.", "Дерьмо дерьмо дерьмо ..."];
		["Заложник", _intrMessage] remoteExec ["BIS_fnc_showSubtitle"];
	},
	/* 10 arguments */     [_anim],
	/* 11 action duration */     3,
	/* 12 priority */     0,
	/* 13 remove on completion */     true,
	/* 14 show unconscious */     false
] remoteExec ["BIS_fnc_holdActionAdd", [0, -2] select isDedicated, true];

ну и во-вторых, использовать такое условие активации триггера:

!(isNil "captives") and {({alive _x} count captives) == 3}

Edited by Schatten, 04 December 2017 - 23:35.

[romylq]

Galet, а можно так что бы у юнита ничего не отнималось из снаряжения и оружия, не присоединялся при этом к группе, и он молчал при освобождении?

Schatten, а можно так что бы у юнита ничего не отнималось из снаряжения и оружия, не присоединялся при этом к группе, и он молчал при освобождении? 

[Schatten]

romylq, убери строки 10-14, 47, 48 и 54.

[romylq]

Schatten, снаряга остается, но он все равно говорит и присоединяется, а в месте с этим еще и тупо не двигается 

[Schatten]

romylq, а где код, который ты используешь?

[romylq]

Schatten, пробовал твой и тот что Galet скинул, удалял и там и там те строчки что ты сказал и все равно

Edited by romylq, 05 December 2017 - 21:52.

[Schatten]

romylq, ну так и опубликуй его здесь, по-нормальному. Ещё напиши как проверял, приведи отчёт из RPT-файла (если ошибки есть)... Может даже миссию приложи.
 
И что значит

он все равно говорит

?

Edited by Schatten, 05 December 2017 - 22:04.

[romylq]

Schatten, пробовал оба кода во 2 и 4 комментарии, при освобождении субтитры появляются, а мне этого не надо 

[Schatten]

Пожалуйста Войдите или Зарегистрируйтесь чтобы увидеть скрытое содержание

Где тут

он все равно говорит ..., а в месте с этим еще и тупо не двигается

и

при освобождении субтитры появляются

?!

P. S.
Присоединение к группе я специально оставил, чтобы бот ко мне подошёл.

[Schatten]

romylq, что, с 5-го декабря так и не удалось удалить строки с указанными номерами?! Это печально...

 

#define	BEHAVIOURS ["ANIM", "AUTOTARGET", "MOVE"]

params [
	["_captive", objNull, [objNull]]
];

if (isNull _captive) exitWith {};

_captive setCaptive true;

_animation = selectRandom [
	"Acts_AidlPsitMstpSsurWnonDnon01",
	"Acts_AidlPsitMstpSsurWnonDnon02",
	"Acts_AidlPsitMstpSsurWnonDnon03",
	"Acts_AidlPsitMstpSsurWnonDnon04",
	"Acts_AidlPsitMstpSsurWnonDnon05",
	"Acts_ExecutionVictim_Loop"
];

_captive switchMove _animation;

if (_animation == "Acts_ExecutionVictim_Loop") then {
	_captive setDamage 0.5;
};

{_captive disableAI _x;} forEach BEHAVIOURS;

_captive allowFleeing 0;
_captive setBehaviour "CARELESS";

[
	_captive,
	"Освободить заложника",
	"\a3\ui_f\data\IGUI\Cfg\HoldActions\holdAction_unbind_ca.paa",
	"\a3\ui_f\data\IGUI\Cfg\HoldActions\holdAction_unbind_ca.paa",
	"true",
	"true",
	{},
	{},
	{
		_captive = _this select 0;
		_actionId = _this select 2;
		_parameters = _this select 3;

		_animation = _parameters select 0;

		if (_animation == "Acts_ExecutionVictim_Loop") then {
			_captive playMove "Acts_ExecutionVictim_Unbow";
		} else {
			_captive switchMove "Acts_AidlPsitMstpSsurWnonDnon_out";
		};

		sleep 5.5;

		{_captive enableAI _x;} forEach BEHAVIOURS;

		_captive setBehaviour "SAFE";

		[_captive, _actionId] remoteExec ["BIS_fnc_holdActionRemove", [0, -2] select isDedicated, true];
	},
	{
		_title = selectRandom [
			"Эй! Я не хочу здесь умереть!",
			"Мужик! Не оставляй меня здесь! Пожалуйста!",
			"ЕСТЬ! ЕСТЬ! ЛЮДИ. ВЫТАЩИ МЕНЯ ОТСЮДА.",
			"Дерьмо дерьмо дерьмо ..."
		];

		["Заложник", _title] remoteExec ["BIS_fnc_showSubtitle"];
	},
	[_animation],
	3,
	0,
	true,
	false
] remoteExec ["BIS_fnc_holdActionAdd", [0, -2] select isDedicated, true];