Сообщений в теме: 17

[Dimon UA]

Не могу перехватить действие кнопки мыши:

так работает при нажатии "G"

(findDisplay 46) displayAddEventHandler ["keyDown", "_this call functionName_keyDown"]; 
functionName_keyDown = { 
    params ["_ctrl", "_dikCode", "_shift", "_ctrlKey", "_alt"]; 
  
    private _handled = false; 
  
    if (!_shift && !_ctrlKey && !_alt) then { 
        if (_dikCode in [(actionKeys "gear") select 0]) then { 
           hint "gear"      ;
      _handled = true; 
        }; 
    }; 
  
    _handled;   
};

 

а так нет при нажатии 'ЛКМ'

(findDisplay 46) displayAddEventHandler ["MouseButtonDown", "_this call functionName_keyDown"]; 
functionName_keyDown = { 
    params ["_ctrl", "_dikCode", "_shift", "_ctrlKey", "_alt"]; 
  
    private _handled = false; 
  

        if (_dikCode in [((actionKeys "defaultAction") select 0)]) then { 
           hint "defaultAction"      ;
      _handled = true; 
        }; 
    _handled;   
}; 

и зажатую ПКМ тоже не могу словить
 

(findDisplay 46) displayAddEventHandler ["MouseButtonDown", "_this call functionName_keyDown"]; 
functionName_keyDown = {   
   
 
        if((_this select 1) in [((actionKeys "zoomTemp") select 0)]) then {  
            hint 'true'; 
        };  
}; 

Сообщение отредактировал Dimon UA: 13 July 2017 - 00:00

[vlad333000]

Dimon UA, перезаписать таким образом можно только клавишы на клавиатуре, все остальные - нет (ЛКМ и остальное, можно через невидимый addAction, для которого определен параметр "shortcut" для действия, которое имеет хотя-бы один вариант раскладки, в точности совпадающий с нужной тебе клавишой, для ЛКМ это "DefaultAction")

PS Для примера можешь посмотреть реализацию предохранителя в ACE Mod

Сообщение отредактировал vlad333000: 13 July 2017 - 00:12

[Dimon UA]

Dimon UA, перезаписать таким образом можно только клавишы на клавиатуре, все остальные - нет (ЛКМ и остальное, можно через невидимый addAction, для которого определен параметр "shortcut" для действия, которое имеет хотя-бы один вариант раскладки, в точности совпадающий с нужной тебе клавишой, для ЛКМ это "DefaultAction")

меня спутала работа кода
 

(findDisplay 46) displayAddEventHandler ["MouseButtonDown", "hint str _this"]; 

он то работает...
+ здесь тоже видит ПКМ
 

[] spawn { 
 waitUntil {inputAction "ZoomTemp" > 0};   
 hint "ZoomTemp Key Pressed"; 
};

ясно. спасибо

PS Для примера можешь посмотреть реализацию предохранителя в ACE Mod

да я уже такое делал - я понял о чем ты

[vlad333000]

Dimon UA, ну вот такие вот они БЕСы, для клавы нормальнуб реализацию переопределения клавиш сделали, а для остального - нет. И не забудь посмотреть предохранитель в ACE Mod, если все же крайне нужно переопределить кнопки на мышке

[Dimon UA]

p=player addAction ["", { 
    playSound3D ['a3\sounds_f\weapons\Other\dry9.wss', _this select 0]; 
}, "", 0, false, true, "ZoomTemp", ""];

Мда, все равно не догоняю что с этим делать - хочу обрубить приближение на ПКМ.
 

[Dimon UA]

я так понимаю что происходит какое-то действие камеры - и так понимаю нужно включить скрипт с противодействием...

[vlad333000]

Dimon UA, потыкал я, походу и этот способ работает только для "DefaultAction", короче БЕСы в своем репертуаре...
Самый простой способ для запрета увеличения - это крутить каждый кадр цикл и, при обнаружении через inputAction, создавать на весь экран непрозрачный control

[Dimon UA]

Dimon UA, потыкал я, походу и этот способ работает только для "DefaultAction", короче БЕСы в своем репертуаре...
Самый простой способ для запрета увеличения - это крутить каждый кадр цикл и, при обнаружении через inputAction, создавать на весь экран непрозрачный control

нашел у КК

Пожалуйста Войдите или Зарегистрируйтесь чтобы увидеть скрытое содержание

KK_fnc_trueZoom = { 
    ( 
        [0.5,0.5]  
        distance2D   
        worldToScreen  
        positionCameraToWorld  
        [0,3,4] 
    ) * ( 
        getResolution  
        select 5 
    ) / 2 
};
[] spawn {
onEachFrame { 
    hintSilent format [ 
        "CURRENT ZOOM: %1x", 
        round (call KK_fnc_trueZoom * 10) / 10 
    ] 
};
};

терь осталось отключить приближение

KK_fnc_trueZoom = {  
    ( [0.5,0.5] distance2D worldToScreen  positionCameraToWorld  [0,3,4] ) * ( getResolution  select 5 ) / 2  
}; 
[] spawn { 
onEachFrame {  
  
        if (round (call KK_fnc_trueZoom * 10) / 10 > 0.3) then {hintsilent "help disable zoom"}; 
}; 
};

первый набросок
 

KK_fnc_trueZoom = { 
    ( [0.5,0.5] distance2D worldToScreen  positionCameraToWorld  [0,3,4] ) * ( getResolution  select 5 ) / 2 
};
[] spawn {
onEachFrame { 
 
        if (round (call KK_fnc_trueZoom * 10) / 10 > 0.3) then {
		
		_camera = "camera" camCreate (positionCameraToWorld  [0,0,0]);
		_camera cameraEffect ["Fixed","BACK"];
		
		};
};
};

хотя так проще наверное как ты влад и сказал
 

[] spawn {  
 waitUntil {inputAction "ZoomTemp" > 0};    
 _camera = "camera" camCreate (positionCameraToWorld  [0,0,0]); 
  _camera cameraEffect ["Fixed","FRONT TOP"];};

Сообщение отредактировал Dimon UA: 13 July 2017 - 02:37

[Dimon UA]

как то так
 

[] spawn {   
while {true} do { 
 waitUntil {inputAction "ZoomTemp" > 0};     
 _camera = "camera" camCreate (positionCameraToWorld  [0,0,0]);  
  _camera cameraEffect ["Fixed","FRONT TOP"]; 
 waitUntil {inputAction "ZoomTemp" == 0}; 
_camera cameraEffect ["TERMINATE","BACK"];  
    camDestroy _camera; 
}; 
};

осталось правильно камеру разместить

[Dimon UA]

непрозрачный control

разьясни плиз по-подробней

[vlad333000]

Dimon UA,

disableSerialization;
private _ctrl = (findDisplay 46) ctrlCreate ["RscStructuredText", -1];

_ctrl ctrlSetPosition [safeZoneXAbs, safeZoneY, safeZoneWAbs, safeZoneH];
_ctrl ctrlSetBackgroundColor [0, 0, 0, 1];
_ctrl ctrlSetTextColor [1, 1, 1, 1];
_ctrl ctrlSetStructuredText (parseText "<t align='center'>Zoom is disabled! Please stop using zoom</t>");
_ctrl ctrlCommit 0;

[Dimon UA]

Dimon UA,

disableSerialization;
private _ctrl = (findDisplay 46) ctrlCreate ["RscStructuredText", -1];

_ctrl ctrlSetPosition [safeZoneXAbs, safeZoneY, safeZoneWAbs, safeZoneH];
_ctrl ctrlSetBackgroundColor [0, 0, 0, 1];
_ctrl ctrlSetTextColor [1, 1, 1, 1];
_ctrl ctrlSetStructuredText (parseText "<t align='center'>Zoom is disabled! Please stop using zoom</t>");
_ctrl ctrlCommit 0;

Спасибо - расшифровал про что ты )

 

[] spawn {  
 disableSerialization;  
 private _ctrl = (findDisplay 46) ctrlCreate ["RscStructuredText", 20001];  
 _ctrl ctrlSetPosition [safeZoneXAbs, safeZoneY, safeZoneWAbs, safeZoneH];  
 _ctrl ctrlSetBackgroundColor [0, 0, 0, 1];  
 _ctrl ctrlSetTextColor [1, 1, 1, 1];  
 _ctrl ctrlSetStructuredText (parseText "<t align='center'>Zoom is disabled! Please stop using zoom</t>");  
 _ctrl ctrlSetFade 1; 
 _ctrl ctrlCommit 0; 
 while {true} do {  
   waitUntil {inputAction "ZoomTemp" > 0 || inputAction "zoomIn" > 0 || inputAction "zoomInToggle" > 0}; 
   _ctrl ctrlSetFade 0; 
  _ctrl ctrlCommit 0; 
   waitUntil {inputAction "ZoomTemp" == 0 || inputAction "zoomIn" == 0 || inputAction "zoomInToggle" == 0}; 
  _ctrl ctrlSetFade 1; 
  _ctrl ctrlCommit 1; 
 };  
}; 

осталось придумать как сделать в идеале - чтобы все видеть и при этом блокировать зум...

Сообщение отредактировал Dimon UA: 15 July 2017 - 13:53

[Dimon UA]

вообщем теперь беда из-за
 

inputAction "zoomInToggle" == 0

на двойное нажатие то реагирует но потом картинка остается приближенной...

переписал с использование КК скрипта
 

KK_fnc_trueZoom = { 
    ( [0.5,0.5] distance2D worldToScreen  positionCameraToWorld  [0,3,4] ) * ( getResolution  select 5 ) / 2 
};

[] spawn { 
	disableSerialization; 
	private _ctrl = (findDisplay 46) ctrlCreate ["RscStructuredText", 20001]; 
	_ctrl ctrlSetPosition [safeZoneXAbs, safeZoneY, safeZoneWAbs, safeZoneH]; 
	_ctrl ctrlSetBackgroundColor [0, 0, 0, 1]; 
	_ctrl ctrlSetTextColor [1, 1, 1, 1]; 
	_ctrl ctrlSetStructuredText (parseText "<t align='center'>Zoom is disabled! Please stop using zoom</t>"); 
	_ctrl ctrlSetFade 1;
	_ctrl ctrlCommit 0;
	while {true} do { 
		 waitUntil {round (call KK_fnc_trueZoom * 10) / 10 > 0.4};
		 _ctrl ctrlSetFade 0;
		_ctrl ctrlCommit 0;
		 waitUntil {round (call KK_fnc_trueZoom * 10) / 10 <= 0.4};
		_ctrl ctrlSetFade 1;
		_ctrl ctrlCommit 1;
	}; 
};

но теперь проблема с тем чтобы смотреть в прицел оптики...

кто знает как можно вычислить смотрит ли игрок в оптику?

[Dimon UA]

пока выкрутился так
 

KK_fnc_trueZoom = { 
    ( [0.5,0.5] distance2D worldToScreen  positionCameraToWorld  [0,3,4] ) * ( getResolution  select 5 ) / 2 
};

[] spawn { 
	disableSerialization; 
	private _ctrl = (findDisplay 46) ctrlCreate ["RscStructuredText", 20001]; 
	_ctrl ctrlSetPosition [safeZoneXAbs, safeZoneY, safeZoneWAbs, safeZoneH]; 
	_ctrl ctrlSetBackgroundColor [0, 0, 0, 1]; 
	_ctrl ctrlSetTextColor [1, 1, 1, 1]; 
	_ctrl ctrlSetStructuredText (parseText "<t align='center'>Zoom is disabled! Please stop using zoom</t>"); 
	_ctrl ctrlSetFade 1;
	_ctrl ctrlCommit 0;
	while {true} do { 
		 waitUntil {round (call KK_fnc_trueZoom * 10) / 10 > 0.4 && {round (call KK_fnc_trueZoom * 10) / 10 <=1}};
		 _ctrl ctrlSetFade 0;
		_ctrl ctrlCommit 0;
		 waitUntil {round (call KK_fnc_trueZoom * 10) / 10 <= 0.4};
		_ctrl ctrlSetFade 1;
		_ctrl ctrlCommit 1;
	}; 
};

[vlad333000]

Пожалуйста Войдите или Зарегистрируйтесь чтобы увидеть скрытое содержание

[Dimon UA]

[ruPal]

Можно переписать конфиги оружия и техники. Делал такое для ванилы, RHS и нескольких других модов год назад

Пожалуйста Войдите или Зарегистрируйтесь чтобы увидеть скрытое содержание

[Dimon UA]

ruPal,да я знаю про твой аддон. Но тут такой момент: чтобы продвинуть аддон нужно попробывать "как в это играть" - для этого нужна тестовая миссия и реализация с помощью скрипта.