Сообщений в теме: 9

[gizmo]

Перерыл весь интернет и форум, не нашёл. Как заставить бота проигрывать анимацию? Постоянно. Всё пробовал, ничего не работает.

Сообщение отредактировал gizmo: 11 November 2014 - 17:49

[SteelRat]

bot disableAI "ANIM";
bot switchMove "animName";

[gizmo]

bot disableAI "ANIM";
bot switchMove "animName";

 

Не работает

[SteelRat]

Вы учитываете тот момент, что не все анимации дадут на выходе, то что вы желаете увидеть?

Имя анимации в студию!

 

И да, я совсем забыл, что проявить инициативу это не про вас, попробуете так сказать по максимуму отключить ботам AI

{bot disableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];

Сообщение отредактировал SteelRat: 11 November 2014 - 20:46

[gizmo]

Анимка : Acts_A_M02_briefing

 

И всё равно не пашет

[SteelRat]

PS

Вот прекрасно работающий в ините бота вариант

0 = this spawn {sleep 3; {_this disableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];
_this switchMove "inbasemoves_patrolling1"}

И естественно, наигравшись с анимацией применяем к боту, но уже от куда то, а не из инита

{_bot enableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];
_bot switchMove "normal";

Анимка : Acts_A_M02_briefing

 

И всё равно не пашет

Вы эту анимацию в просмотрщике крутили?

[gizmo]

PS

Вот прекрасно работающий в ините бота вариант

0 = this spawn {sleep 3; {_this disableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];
_this switchMove "inbasemoves_patrolling1"}

И естественно, наигравшись с анимацией применяем к боту, но уже от куда то, а не из инита

{_bot enableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];
_bot switchMove "normal";

Анимка : Acts_A_M02_briefing

 

И всё равно не пашет

Вы эту анимацию в просмотрщике крутили?

 

Ваша анимация работает, анимацию крутил, всё ок. Но ваша работает а моя нет, видимо с ней что-то не то.

Поставил другую анимку, работает. Кстати, а можно исправить телепортацию? Там где идёт "шов" анимки чувак телепортируется. Не стоит на месте.

Сообщение отредактировал gizmo: 11 November 2014 - 21:12

[SteelRat]

Может найдёте здесь про брифинг

 

/*
	Author: Jiri Wainar

	Description:
	Play set of ambient animations on given unit.

	Remarks:
	* Can handle several different anims and auto-switching between them.
	* Detects nearby units with the same animation set and tries to select different animations.
	* A game logic is created on units position and animated unit is then attached to it, to prevent possible problems, like player pushing units around.
	* The unit can be snapped to a set snappoint to prevent game from repositioning the unit.
		* The snappoint is automatically detected, snap distance is 2 meters (in top-down view, ignoring vertical info).
		* To position unit vertically, move its snappoint up/down.
		* A snappoint is a (cyan colored) helper "Sign_Pointer_Cyan_F".
		* This is extremely handy if the unit needs to be placed near object(s) - like on chair near a table.

	Parameter(s):
	0: OBJECT - unit the anim & gear changes are going to be applied to
	1: STRING - animation set id, describing what the unit's action looks like.
	   > "STAND"		- standing still, slightly turning to the sides, with rifle weapon
	   > "STAND_IA"		- standing still, slightly turning to the sides, with rifle weapon
	   > "STAND_U1-3"	- standing still, slightly turning to the sides, no weapon
	   > "WATCH1-2"		- standing and turning around, with rifle weapon
	   > "GUARD"		- standing still, like on guard with hands behing the body
	   > "LISTEN_BRIEFING"  - standing still, hands behind back, recieving briefing / commands, no rifle.
	   > "LEAN_ON_TABLE"	- standing while leaning on the table
	   > "LEAN"		- standing while leaning (on wall)
	   > "BRIEFING"		- standing, playing ambient briefing loop with occasional random moves
	   > "BRIEFING_POINT_LEFT"	- contains 1 extra pointing animation, pointing left & high
	   > "BRIEFING_POINT_RIGHT"	- contains 1 extra pointing animation, pointing right & high
	   > "BRIEFING_POINT_TABLE"	- contains 1 extra pointing animation, pointing front & low, like at table
	   > "SIT1-3"		- sitting on chair or bench, with rifle weapon
	   > "SIT_U1-3"		- sitting on chair or bench, without weapon
	   > "SIT_AT_TABLE"	- sitting @ table, hands on table
	   > "SIT_HIGH1-2" 	- sitting on taller objects like a table or wall, legs not touching the ground. Needs a rifle!
	   > "SIT_LOW"		- sitting on the ground, with weapon.
	   > "SIT_LOW_U"	- sitting on the ground, without weapon.
	   > "SIT_SAD1-2"	- sitting on a chair, looking very sad.
	   > "KNEEL"		- kneeling, with weapon.
	   > "PRONE_INJURED_U1-2" - laying wounded, back on the ground, wothout weapon
	   > "PRONE_INJURED"	- laying wounded & still, back on the ground, with or without weapon
	   > "KNEEL_TREAT"	- kneeling while treating the wounded
	   > "REPAIR_VEH_PRONE"	- repairing vehicle while laying on the ground (under the vehicle)
	   > "REPAIR_VEH_KNEEL"	- repairing vehicle while kneeling (like changing a wheel)
	   > "REPAIR_VEH_STAND"	- repairing/cleaning a vehicle while standing

	2: STRING - equipment level id, describing how heavily is the unit equipped.
	   > "NONE"  		- no goggles, headgear, vest, weapon
	   > "LIGHT"  		- no goggles, headgear, vest
	   > "MEDIUM" 		- no goggles, headgear
	   > "FULL"  		- no goggles
	   > "ASIS"  		- no touches to the gear
	   > "RANDOM" (default)	- gear is randomized according to the animation set

	3: OBJECT 	- object unit to snap to; function won't try to search for the closest snappoint and will use this snappoint instead
	4: BOOL		- function will try to interpolate into the ambient animation, if the interpolateTo link exists
			- it is not officialy supported, so it's disabled by default
			- works only for transitions from (some) default A3 stances to sets "STAND", "SIT_LOW" and "KNEEL"

	Returns:
	-

	Example:
	[this,"SIT_HIGH2"] call BIS_fnc_ambientAnim;
*/

[SteelRat]

Анимка : Acts_A_M02_briefing

 

И всё равно не пашет

 

Блин, я с вас не устану удивляться, вы могли нормальным русским языком написать.

 

Анимация проигрывается однократно, а не вот это

 

И всё равно не пашет

[SteelRat]

 Анимка : Acts_A_M02_briefing

 

 

Тут дело в том, что эта и подобные ей анимации не зацикливаются, они проигрываются в комплекте с другими.

Но, если очень хочется, вот лекарство

0 = [this, "Acts_A_M02_briefing"] spawn {
	sleep 3;
	
	_unit = _this select 0;
	_anim = _this select 1;
	
	anim_play = true;
	{_unit disableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];
	
	_unit setVariable ["AnimCode", {
		if (anim_play && alive (_this select 0)) then {
			(_this select 0) switchmove (_this select 1);
		} else {
			(_this select 0) removeEventHandler ["animDone", (_this select 0) getVariable "EH_animDone"];
			(_this select 0) setVariable ["EH_animDone", nil];
			(_this select 0) setVariable ["AnimCode", nil];
			{(_this select 0) enableAI _x} forEach ["ANIM", "AUTOTARGET", "FSM", "MOVE", "TARGET"];
			(_this select 0) switchmove "normal";
		};
	}];
	
	[_unit, _anim] call (_unit getVariable "AnimCode");
	waitUntil {sleep 0.01; animationState _unit == _anim};
	_unit setVariable ["EH_animDone", _unit addEventHandler ["animDone", {[(_this select 0), (_this select 1)] call ((_this select 0) getVariable "AnimCode")}]];
}

Что бы прервать воспроизведение, исполнить откуда либо эту строку

anim_play = false;

Анимация доиграет до конца и прекратит воспроизведение.