Сообщений в теме: 4

[STEAL92]

При написании скриптов загорелся идеей создать скрипт на открытие и закрытие техники, но столкнулся с проблемой, что не могу зациклить цикл так чтобы одно действие (addAction) появлялось, а другое исчезало, подскажите как это сделать, внизу код с описанием строк в нем.

 

 

/* 0 = [] execVM "addAction.sqf"; */

respMash addAction ["<t color='#00FF00'>Развернуть КШМ</t>", 

{ 

myResp = [west, "respMash"] call BIS_fnc_addRespawnPosition;//Создает точку респауна в технике 

 

player addEventHandler ["GetInMan",//Создаем событие GetInMan - если человек внутри

{

["respMash","player"];//Параметры GetInMan = true 

player moveOut respMash;//Действие при true. Высадится игроку

}];

 

respMash setVehicleLock "LOCKED";//Полностью блокирует технику 

hint parseText "<t size='2.0'>КШМ РАЗВЕРНУТ</t>";//Выводит хинт

respMash removeAction 0;//удаляет строчку экшена Развернуть КШМ

respMash addAction ["<t color='#FF0000'>Свернуть КШМ</t>",//Параметры addAction Свернуть КШМ  

{

myResp = [west, 0] call BIS_fnc_removeRespawnPosition;//Удаляем точку респауна в технике

respMash setVehicleLock "UNLOCKED";//Полностью разблокируем технику технику 

player removeAllEventHandlers "GetInMan";

hint parseText "<t size='2.0'>КШМ СВЕРНУТ</t>";//Выводит хинт

respMash removeAction 1;

},

nil, 1.5, true, true, "", "", 5];//Параметры addAction Свернуть КШМ

 

 

player moveOut respMash;//Высадится игроку если он телепортируется в respMash = машина

 

},

nil, 1.5, true, true, "", "", 5];//Параметры addAction Развернуть КШМ

 

 

 

 

 

 

respMash addEventHandler ["Killed",//Событие при котором техника уничтожена

{

myResp = [west, 0] call BIS_fnc_removeRespawnPosition;

respMash removeAction 0;

respMash removeAction 1;

}];

 

 

Прикрепленные файлы

•  RAZRABOTKA%20K%20III%20M.VR.rar   5.13К   0 Количество загрузок:

Сообщение отредактировал STEAL92: 05 May 2024 - 20:20

[Schatten]

столкнулся с проблемой, что не могу зациклить цикл так чтобы одно действие (addAction) появлялось, а другое исчезало, подскажите как это сделать

Нужно использовать не глобальные переменные и магические числа (respMash removeAction 0), а локальные.

[STEAL92]

 

столкнулся с проблемой, что не могу зациклить цикл так чтобы одно действие (addAction) появлялось, а другое исчезало, подскажите как это сделать

Нужно использовать не глобальные переменные и магические числа (respMash removeAction 0), а локальные.

 

Мне не понятно как это сделать. Я беру имя переменной respMash поскольку эта переменная прописана в параметрах этого объекта и получается что к нему и цепляю все addAction. 

Видел как применяют другую конструкцию, в ините обекта прописывают addAction и скрипт но там берется this как я понимаю тоже глобально (без _). Если можно скинь видео где с объектом в скрипте применяются локальные переменные, мне надо наглядно видеть, на словах я плохо понимаю.

 

[STEAL92]

 

столкнулся с проблемой, что не могу зациклить цикл так чтобы одно действие (addAction) появлялось, а другое исчезало, подскажите как это сделать

Нужно использовать не глобальные переменные и магические числа (respMash removeAction 0), а локальные.

 

в том то и дело я не знаю как это сделать все что написано, было взято из источников, других видео, методом проб и ошибок у меня получилось сделать addAction и он работает, я хочу его довести до ума. Мне бы пример о том что ты говоришь в виде видео, чтоб наглядно было, так мне пока сложно понять.

[Schatten]

Если можно скинь видео где с объектом в скрипте применяются локальные переменные, мне надо наглядно видеть, на словах я плохо понимаю.

Разбирайся:

addUnfoldHqVehicleAction = {
    params ["_vehicle"];

    private _actionId = _vehicle addAction [
        "<t color='#00FF00'>Развернуть КШМ</t>", 
        {
            params ["_vehicle", "_caller", "_actionId"];

            _vehicle removeAction _actionId;

            if (_caller in _vehicle) then {
                _caller moveOut _vehicle;
            };

            _vehicle setVehicleLock "LOCKED";

            _eventHandlerId = _vehicle addEventHandler [
                "GetIn",
                {
                    params ["_vehicle", "", "_unit"];

                    _unit moveOut _vehicle;
                }
            ];

            _respawnPositionInfo = [blufor, _vehicle] call BIS_fnc_addRespawnPosition;

            [_vehicle] call addFoldHqVehicleAction;

            _vehicle setVariable ["unfoldHqVehicleActionId", nil];
            _vehicle setVariable ["getInEventHandlerId", _eventHandlerId];
            _vehicle setVariable ["respawnPositionInfo", _respawnPositionInfo];

            hint (parseText "<t size='2.0'>КШМ РАЗВЕРНУТ</t>");
        },
        nil, 1.5, true, true, "", "true", 5
    ];

    _vehicle setVariable ["unfoldHqVehicleActionId", _actionId];
};
addFoldHqVehicleAction = {
    params ["_vehicle"];

    private _actionId = _vehicle addAction [
        "<t color='#FF0000'>Свернуть КШМ</t>",
        {
            params ["_vehicle", "_caller", "_actionId"];

            _vehicle removeAction _actionId;

            _respawnPositionInfo = _vehicle getVariable ["respawnPositionInfo", []];
            _eventHandlerId = _vehicle getVariable ["getInEventHandlerId", -1];

            if (_respawnPositionInfo isNotEqualTo []) then {
                _respawnPositionInfo call BIS_fnc_removeRespawnPosition;
            };
            if (_eventHandlerId >= 0) then {
                _vehicle removeEventHandler ["GetIn", _eventHandlerId];
            };

            _vehicle setVehicleLock "UNLOCKED";

            [_vehicle] call addUnfoldHqVehicleAction;

            _vehicle setVariable ["foldHqVehicleActionId", nil];
            _vehicle setVariable ["getInEventHandlerId", nil];
            _vehicle setVariable ["respawnPositionInfo", nil];

            hint (parseText "<t size='2.0'>КШМ СВЕРНУТ</t>");
        },
        nil, 1.5, true, true, "", "true", 5
    ];

    _vehicle setVariable ["foldHqVehicleActionId", _actionId];
};

[respMash] call addUnfoldHqVehicleAction;

respMash addEventHandler [
    "Killed",
    {
        params ["_vehicle"];

        _respawnPositionInfo = _vehicle getVariable ["respawnPositionInfo", []];

        if (_respawnPositionInfo isNotEqualTo []) then {
            _respawnPositionInfo call BIS_fnc_removeRespawnPosition;
        };

        _vehicle setVariable ["respawnPositionInfo", nil];

        {
            _actionId = _vehicle getVariable [_x, -1];

            if (_actionId >= 0) then {
                _vehicle removeAction _actionId;
            };

            _vehicle setVariable [_x, nil];
        } forEach ["unfoldHqVehicleActionId", "foldHqVehicleActionId"];
    }
];